Commit eca2f08f authored by Philip Müller's avatar Philip Müller
Browse files

[pkg-upd] 3.34.0-1.1

- try to fix Mate session issues
parents
Loading
Loading
Loading
Loading

PKGBUILD

0 → 100644
+62 −0
Original line number Diff line number Diff line
# Maintainer: Jan De Groot <jgc@archlinux.org>

pkgname=gnome-keyring
pkgver=3.34.0
pkgrel=1.1
epoch=1
pkgdesc="Stores passwords and encryption keys"
url="https://wiki.gnome.org/Projects/GnomeKeyring"
arch=(x86_64)
license=(GPL LGPL)
depends=(gcr libcap-ng pam openssh)
makedepends=(git docbook-xsl python)
groups=(gnome)
install=gnome-keyring.install
_commit=d463f42495484437de8cec69bea9b6814ee32479  # tags/3.34.0^0
source=("git+https://gitlab.gnome.org/GNOME/gnome-keyring.git#commit=$_commit"
        add-cinnamon.diff
        https://gitlab.gnome.org/GNOME/gnome-keyring/uploads/0727b3f0f0772e685a81d0ab55c96553/revert-synchronuous.patch)
sha256sums=('SKIP'
            'd05210f5b0a7d4b22c0dff2854854af2eb5708aa2b296095e070dca68e9f815a'
            '12b6a0980aaadc09d2ee0de613ce75ce54d55a2be4da614e07c699f9cc40a119')

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/-/+/g'
}

prepare() {
  cd $pkgname
  git apply -3 ../add-cinnamon.diff

  # https://github.com/mate-desktop/mate-session-manager/issues/222
  # https://bugs.archlinux.org/task/63995
  # https://gitlab.gnome.org/GNOME/gnome-keyring/issues/40
  patch -p1 -i ../revert-synchronuous.patch

  NOCONFIGURE=1 ./autogen.sh
}

build() {
  cd $pkgname
  ./configure --prefix=/usr \
    --sysconfdir=/etc \
    --localstatedir=/var \
    --libexecdir=/usr/lib \
    --with-pam-dir=/usr/lib/security \
    --disable-static \
    --disable-schemas-compile
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

check() {
  cd $pkgname
  # Secure memory tests fail
  dbus-run-session make -k check || :
}

package() {
  cd $pkgname
  make DESTDIR="$pkgdir" install
}

add-cinnamon.diff

0 → 100644
+44 −0
Original line number Diff line number Diff line
 daemon/gnome-keyring-pkcs11.desktop.in.in  | 2 +-
 daemon/gnome-keyring-secrets.desktop.in.in | 2 +-
 daemon/gnome-keyring-ssh.desktop.in.in     | 2 +-
 3 files changed, 3 insertions(+), 3 deletions(-)

diff --git c/daemon/gnome-keyring-pkcs11.desktop.in.in i/daemon/gnome-keyring-pkcs11.desktop.in.in
index b43e1e9d..80434cbd 100644
--- c/daemon/gnome-keyring-pkcs11.desktop.in.in
+++ i/daemon/gnome-keyring-pkcs11.desktop.in.in
@@ -3,7 +3,7 @@ Type=Application
 Name=Certificate and Key Storage
 Comment=GNOME Keyring: PKCS#11 Component
 Exec=@bindir@/gnome-keyring-daemon --start --components=pkcs11
-OnlyShowIn=GNOME;Unity;MATE;
+OnlyShowIn=GNOME;Unity;MATE;Cinnamon;
 NoDisplay=true
 X-GNOME-Autostart-Phase=PreDisplayServer
 X-GNOME-AutoRestart=false
diff --git c/daemon/gnome-keyring-secrets.desktop.in.in i/daemon/gnome-keyring-secrets.desktop.in.in
index dd9deec7..b6d7b2d0 100644
--- c/daemon/gnome-keyring-secrets.desktop.in.in
+++ i/daemon/gnome-keyring-secrets.desktop.in.in
@@ -3,7 +3,7 @@ Type=Application
 Name=Secret Storage Service
 Comment=GNOME Keyring: Secret Service
 Exec=@bindir@/gnome-keyring-daemon --start --components=secrets
-OnlyShowIn=GNOME;Unity;MATE;
+OnlyShowIn=GNOME;Unity;MATE;Cinnamon;
 NoDisplay=true
 X-GNOME-Autostart-Phase=PreDisplayServer
 X-GNOME-AutoRestart=false
diff --git c/daemon/gnome-keyring-ssh.desktop.in.in i/daemon/gnome-keyring-ssh.desktop.in.in
index 38aa24cb..163ff554 100644
--- c/daemon/gnome-keyring-ssh.desktop.in.in
+++ i/daemon/gnome-keyring-ssh.desktop.in.in
@@ -3,7 +3,7 @@ Type=Application
 Name=SSH Key Agent
 Comment=GNOME Keyring: SSH Agent
 Exec=@bindir@/gnome-keyring-daemon --start --components=ssh
-OnlyShowIn=GNOME;Unity;MATE;
+OnlyShowIn=GNOME;Unity;MATE;Cinnamon;
 X-GNOME-Autostart-Phase=PreDisplayServer
 X-GNOME-AutoRestart=false
 X-GNOME-Autostart-Notify=true

gnome-keyring.install

0 → 100644
+7 −0
Original line number Diff line number Diff line
post_install() {
  setcap cap_ipc_lock+ep usr/bin/gnome-keyring-daemon
}

post_upgrade() {
  post_install
}