PKGBUILD

# Maintainer: Stefano Capitani <stefano@manjaro.org>
# Maintainer: Bernhard Landauer <oberon@manjaro.org>
# Maintainer: Mark Wagie <mark@manjaro.org>

# Maintainer: Davi da Silva Böger <dsboger@gmail.com>
# Contributor: Manuel Hüsers <manuel.huesers@uni-ol.de>
# Contributor: Fernando Fernandez <fernando@softwareperonista.com.ar>
# Contributor: Ionut Biru <ibiru@archlinux.org>
# Contributor: Jason Edson <jaysonedson@gmail.com>

pkgbase=vte3-notification
pkgname=("${pkgbase}" 'vte-notification-common')
pkgver=0.62.1
pkgrel=1
pkgdesc="Virtual Terminal Emulator widget with Fedora patches"
arch=('x86_64')
url="https://wiki.gnome.org/Apps/Terminal/VTE"
license=('LGPL')
depends=('gtk3' 'pcre2' 'gnutls' 'fribidi' 'systemd-libs')
makedepends=('gobject-introspection' 'vala' 'git' 'gtk-doc' 'gperf' 'meson')

# Fedora patches: https://src.fedoraproject.org/rpms/vte291/tree/
_frepourl='https://src.fedoraproject.org/rpms/vte291'
_frepobranch='f33'
_fpatchfile='vte291-cntnr-precmd-preexec-scroll.patch'
_fcommit='623150318ddb9a9a5797b4b9f74e6bb5d7ad7715'

# VTE source ref
_vtetag=${pkgver}

source=(
	"git+https://gitlab.gnome.org/GNOME/vte.git#tag=$_vtetag"
	"${_fpatchfile}-${_fcommit}::${_frepourl}/raw/${_fcommit}/f/${_fpatchfile}"
	'add-zsh-notification-support.patch')
sha256sums=('SKIP'
            '58103faff3bd492bcfd2a4c5b981fe951f3a96aca55edb30526563dad2e89842'
            '93cd9c7c1fe4001a56e5a6357b6ffd79ce030ac04342801792500f9e44ff79ed')

prepare () {
	cd vte
	patch -p1 -i "../${_fpatchfile}-${_fcommit}"
}

build() {
	arch-meson vte build -D docs=true -D b_lto=false
	meson compile -C build
}

check() {
	meson test -C build --print-errorlogs
}

_pick() {
	local p="$1" f d; shift
	for f; do
		d="$srcdir/$p/${f#$pkgdir/}"
		mkdir -p "$(dirname "$d")"
		mv "$f" "$d"
		rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
	done
}

package_vte3-notification(){
	depends+=('vte-notification-common')
	provides=("vte3=${pkgver}" 'libvte-2.91.so')
	conflicts=('vte3')

	DESTDIR="${pkgdir}" meson install -C build

	### Split vte-common
	_pick vte-common "$pkgdir"/etc/profile.d
	_pick vte-common "$pkgdir"/usr/lib/{systemd,vte-urlencode-cwd}
}

package_vte-notification-common() {
	pkgdesc="Files shared by VTE libraries"
	depends=('sh')
	provides=("vte-common=${pkgver}")
	conflicts=('vte-common')

	mv vte-common/* "$pkgdir"
}