PKGBUILD

# Maintainer: Stefano Capitani <stefano@manjaro.org>
# Maintainer: Bernhard Landauer <oberon@manjaro.org>
# Maintainer: Mark Wagie <mark@manjaro.org>

# Contributor: Jason Edson <jaysonedson@gmail.com>
# Contributor: Davi da Silva Böger <dsboger@gmail.com>
# Contributor: Manuel Hüsers <manuel.huesers@uni-ol.de>
# Contributor: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Ionut Biru <ibiru@archlinux.org>

pkgbase=vte3-notification
pkgname=("${pkgbase}" 'vte-notification-common')
pkgver=0.64.2
pkgrel=1
pkgdesc="Virtual Terminal Emulator widget with Fedora patches"
arch=('x86_64')
url="https://wiki.gnome.org/Apps/Terminal/VTE"
license=('LGPL')
depends=('gtk3' 'pcre2' 'gnutls' 'fribidi' 'systemd')
makedepends=('gobject-introspection' 'vala' 'git' 'gtk-doc' 'gperf' 'meson')

# Fedora patches: https://src.fedoraproject.org/rpms/vte291/tree/
_frepourl='https://src.fedoraproject.org/rpms/vte291'
_frepobranch='rawhide'
_fpatchfile100='vte291-cntnr-precmd-preexec-scroll.patch'
_fcommit='d2277d0702dcc901aaeb23b7c04512d4a1424575'

# VTE source ref
_vtetag=${pkgver}

source=(
	"git+https://git.gnome.org/browse/vte#tag=$_vtetag"
	"${_fpatchfile100}-${_fcommit}::${_frepourl}/raw/${_fcommit}/f/${_fpatchfile100}")
sha256sums=('SKIP'
            '9a0ed5e07108a760c00c9d451316529e91852ea8798dd39cd0b3081e477c2ce5')

prepare () {
	cd vte
	patch -p1 -i "../${_fpatchfile100}-${_fcommit}"
}

build() {
	arch-meson vte build \
		-D b_lto=false \
		-D docs=true
	meson compile -C build
}

_pick() {
	local p="$1" f d; shift
	for f; do
		d="$srcdir/$p/${f#$pkgdir/}"
		mkdir -p "$(dirname "$d")"
		mv "$f" "$d"
		rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
	done
}

package_vte3-notification(){
	depends+=('vte-notification-common')
	provides=("vte3=${pkgver}" 'libvte-2.91.so')
	conflicts=('vte3')

	meson install -C build --destdir "$pkgdir"

	### Split vte-common
	_pick vte-common "$pkgdir"/etc/profile.d
	_pick vte-common "$pkgdir"/usr/lib/{systemd,vte-urlencode-cwd}
}

package_vte-notification-common() {
	pkgdesc="Files shared by VTE libraries"
	depends=('sh')
	provides=("vte-common=${pkgver}")
	conflicts=('vte-common')

	mv vte-common/* "$pkgdir"
}