PKGBUILD

# Maintainer: Stefano Capitani <stefano@manjaro.org>
# Maintainer: Bernhard Landauer <oberon@manjaro.org>
# Maintainer: Mark Wagie <mark@manjaro.org>

# Contributor: Jason Edson <jaysonedson@gmail.com>
# Contributor: Davi da Silva Böger <dsboger@gmail.com>
# Contributor: Manuel Hüsers <manuel.huesers@uni-ol.de>
# Contributor: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Ionut Biru <ibiru@archlinux.org>

pkgbase=vte3-notification
pkgname=(vte-notification-common vte3-notification vte4-notification)
pkgver=0.72.2
pkgrel=2
pkgdesc="Virtual Terminal Emulator widget with Fedora patches"
arch=(x86_64)
url="https://wiki.gnome.org/Apps/Terminal/VTE"
license=(LGPL)
makedepends=(
  fribidi
  gi-docgen
  git
  gnutls
  gobject-introspection
  gperf
  gtk3
  gtk4
  meson
  pcre2
  systemd
  vala
)
options=(!lto)
_commit=854e56263454077ab009aaff67f1afe0dbd52878  # tags/0.72.2^0

# Fedora patches: https://src.fedoraproject.org/rpms/vte291/tree/
_frepourl='https://src.fedoraproject.org/rpms/vte291'
_frepobranch='rawhide'
_fpatchfile0='vte291-cntnr-precmd-preexec-scroll.patch'
_fcommit='44a011ad2c2c775c6c8d5de6e7af4e13eb334333'

# VTE source ref
_vtetag=${pkgver}

source=(
  "git+https://gitlab.gnome.org/GNOME/vte.git#commit=$_commit"
  "${_fpatchfile0}-${_fcommit}::${_frepourl}/raw/${_fcommit}/f/${_fpatchfile0}")
sha256sums=('SKIP'
            '4e0dc098681f78241178f8aa33b6a59adf78bb13686540f0664285e080301b5b')

pkgver() {
  cd vte
  git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
}

prepare () {
  cd vte
  patch -p1 -i "../${_fpatchfile0}-${_fcommit}"
}

build() {
  local meson_options=(
    -D b_lto=false
    -D docs=false
    -D gtk4=true
  )

  arch-meson vte build "${meson_options[@]}"
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

_pick() {
  local p="$1" f d; shift
  for f; do
    d="$srcdir/$p/${f#$pkgdir/}"
    mkdir -p "$(dirname "$d")"
    mv "$f" "$d"
    rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
  done
}

package_vte-notification-common() {
  pkgdesc+=" (common files)"
  depends=(sh)
  provides=("vte-common=${pkgver}")
  conflicts=('vte-common')

  meson install -C build --destdir "$pkgdir"

  cd "$pkgdir"

  _pick gtk3 usr/bin/vte-2.91
  _pick gtk3 usr/include/vte-2.91
  _pick gtk3 usr/lib/libvte-2.91.so*
  _pick gtk3 usr/lib/pkgconfig/vte-2.91.pc
  _pick gtk3 usr/lib/girepository-1.0/Vte-2.91.typelib
  _pick gtk3 usr/share/gir-1.0/Vte-2.91.gir
  _pick gtk3 usr/share/glade
  _pick gtk3 usr/share/vala/vapi/vte-2.91.{deps,vapi}

  _pick gtk4 usr/bin/vte-2.91-gtk4
  _pick gtk4 usr/include/vte-2.91-gtk4
  _pick gtk4 usr/lib/libvte-2.91-gtk4.so*
  _pick gtk4 usr/lib/pkgconfig/vte-2.91-gtk4.pc
  _pick gtk4 usr/lib/girepository-1.0/Vte-3.91.typelib
  _pick gtk4 usr/share/gir-1.0/Vte-3.91.gir
  _pick gtk4 usr/share/vala/vapi/vte-2.91-gtk4.{deps,vapi}
}

package_vte3-notification(){
  pkgdesc+=" (GTK3)"
  depends=(
    fribidi
    gnutls
    gtk3
    pcre2
    systemd
    vte-notification-common
  )
  provides=("vte3=${pkgver}" 'libvte-2.91.so')
  conflicts=('vte3')

  mv gtk3/* "$pkgdir"
}

package_vte4-notification() {
  pkgdesc+=" (GTK4)"
  depends=(
    fribidi
    gnutls
    gtk4
    pcre2
    systemd
    vte-notification-common
  )
  provides+=("vte4=${pkgver}" libvte-2.91-gtk4.so)
  conflicts=(vte4)

  mv gtk4/* "$pkgdir"
}